Objectifs

• Commander 4 électrovannes (3 zones arrosage + 1 remplissage piscine)
• Détecter le manque d’eau grace à un flotteur dans la citerne d’eau
• Controler la température et l’humidité (surtout l’humidité extérieur pour savoir s’il a plu)

Schéma de principe de l’installation

Configuration de ESP Easy du Sonoff Pow R2 (Pompe Arrosage) 192.168.0.126

Onglet Controllers

Onglet Hardware

Onglet Devices

Onglet Rules

Rules Set 1 (faut juste clignoter la LED bleue à la mise sous tension)

On System#Boot do // Trigger de boot
gpio,13,0 // LED ON
timerSet,1,1 // Initialiser Timer 1 dans 1 seconde
timerSet,3,10 // Initialiser Timer 3 dans 10 secondes pour tout éteindre
endon

On Rules#Timer=1 do
gpio,13,1 // LED OFF
timerSet,2,1 // Initialiser Timer 2 dans 1 seconde
endon

On Rules#Timer=2 do
gpio,13,0 // LED ON
timerSet,1,1 // Initialiser Timer 1 dans 1 seconde pour relancer Timer 1
endon

On Rules#Timer=3 do
timerSet,1,0 // Arreter Timer1
timerSet,2,0 // Arreter Timer2
gpio,13,1 // LED OFF
endon

Rules Set 2 (Etablit le lien entre le bouton GPIO0=Bouton et le relais GPIO12=Jus)

on Bouton#Bouton do
if [Jus#Jus]=1
GPIO,12,0 // Éteint
else
GPIO,12,1 // Allume
endif
endon

Rules Set 3 (Etablit le lien entre le capteur de niveau d’eau GPIO5 et la led bleue)

Nota : A ce stade, l’absence d’eau n’est pas prise en compte à cause d’un souci physique du capteur, cela viendra dans une prochaine mise à jour de cette page

on GPIO5#GPIO5=1 do
GPIO,13,1
endon

on GPIO5#GPIO5=0 do
GPIO,13,0
endon

Configuration Jeedom du Sonoff Pow R2 (Pompe Arrosage) 192.168.0.126

Nota : Les commandes ajoutées ne sont pas obligatoires, elles permettent de tester manuellement le bon fonctionnement

Configuration de ESP Easy du Sonoff 4CH Pro (Arrosage) 192.168.0.193

Onglet Controllers

Onglet Hardware

Onglet Devices

Onglet Rules

Rules Set 1 (Lance l’arrosage à 22h ou sur réception de la commande LanceArrosage)

on Clock#Time=All,22:00 do
if [LedBleue#LedBleue]=1
let,1,1 // compteur de boucles (de 3 zones) de 1 à %v2%
let,2,8 // nombre de boucles (de 3 zones)
let,3,40 // temps d'arrosage de chaque zone en secondes
gpio,15,1 // Relais4=ON
timerSet,5,1 //Initialise le Timer 1 à 1s
endif
endon

on LanceArrosage do
if [LedBleue#LedBleue]=1
let,1,1 // compteur de boucles (de 3 zones) de 1 à %v2%
let,2,5 // nombre de boucles (de 3 zones)
let,3,%eventvalue% // temps d'arrosage de chaque zone en secondes
gpio,15,1 // Relais4=ON
timerSet,5,1 //Initialise le Timer 1 à 1s
endif
endon

on StopArrosage do
gpio,15,0 // Relais4=OFF
gpio,12,0 // Relais1=OFF
gpio,4,0 // Relais3=OFF
gpio,5,0 // Relais2=OFF
timerSet,5,0 //Arrête le Timer 1
timerSet,6,0 //Arrête le Timer 2
timerSet,7,0 //Arrête le Timer 3
timerSet,8,0 //Arrête le Timer 4
endon

On Rules#Timer=5 do // Zone1=ON // Zone3=OFF
gpio,12,1 // Relais1
gpio,4,0 // Relais3
timerSet,6,%v3% // Lance timer 2 dans %v3% secondes
endon

On Rules#Timer=6 do // Zone1=OFF // Zone2=ON
gpio,12,0 // Relais1
gpio,5,1 // Relais2
timerSet,7,%v3% // Lance timer 3 dans %v3% secondes
endon

On Rules#Timer=7 do // Zone2=OFF // Zone3=ON
gpio,5,0 // Relais2
gpio,4,1 // Relais3
timerSet,8,%v3% // Lance timer 4 dans %v3% secondes
endon

On Rules#Timer=8 do
if %v1%<%v2% do
let,1,%v1%+1
timerSet,5,1 //Lance timer 5
else
gpio,15,0 // Relais4=OFF
gpio,4,0 // Relais3
endif
endon

Rules Set 2 (Etablit le lien entre les boutons et les relais  )

on Bouton1#Bouton1=1 do
if [Relais1#Relais1]=1
GPIO,12,0
else
GPIO,12,1
GPIO,15,1 // Allume Alim 24v
timerSet,4,3600 //Initialise le Timer 4 à 1h
endif
endon

on Bouton1 do
if [Relais1#Relais1]=1
GPIO,12,0
else
GPIO,12,1
GPIO,15,1 // Allume Alim 24v
timerSet,4,3600 //Initialise le Timer 4 à 1h
endif
endon

on Bouton2#Bouton2=1 do
if [Relais2#Relais2]=1
GPIO,5,0
else
GPIO,5,1
GPIO,15,1 // Allume Alim 24v
timerSet,4,3600 //Initialise le Timer 4 à 1h
endif
endon

on Bouton2 do
if [Relais2#Relais2]=1
GPIO,5,0
else
GPIO,5,1
GPIO,15,1 // Allume Alim 24v
timerSet,4,3600 //Initialise le Timer 4 à 1h
endif
endon

on Bouton3#Bouton3=1 do
if [Relais3#Relais3]=1
GPIO,4,0
else
GPIO,4,1
GPIO,15,1 // Allume Alim 24v
timerSet,4,3600 //Initialise le Timer 4 à 1h
endif
endon

on Bouton3 do
if [Relais3#Relais3]=1
GPIO,4,0
else
GPIO,4,1
GPIO,15,1 // Allume Alim 24v
timerSet,4,3600 //Initialise le Timer 4 à 1h
endif
endon

on Bouton4 do
GPIO,15,1 // Allume Alim 24v
timerSet,4,%eventvalue% //Initialise le Timer 4 à %eventvalue%
endon

on Bouton4#Bouton4=1 do
if [Relais4#Relais4]=1
GPIO,15,0 // Éteint Alim 24v
else
GPIO,15,1 // Allume Alim 24v
endif
endon

On Rules#Timer=4 do
gpio,15,0 // Éteint Alim 24v
endon

 

Rules Set 3 (Cale l’état au démarrage et faut clignoter la Led Bleue)

On System#Boot do // Trigger de boot
gpio,15,0 // Relais4=OFF
gpio,12,0 // Relais1=OFF
gpio,4,0 // Relais3=OFF
gpio,5,0 // Relais2=OFF
gpio,13,1 // LED OFF
timerSet,1,1 // Initialiser Timer 1 dans 1 seconde
timerSet,3,10 // Initialiser Timer 3 dans 10 secondes pour tout éteindre
endon

On Rules#Timer=1 do
gpio,13,0 // LED ON
timerSet,2,1 // Initialiser Timer 2 dans 1 seconde
endon

On Rules#Timer=2 do
gpio,13,1 // LED OFF
timerSet,1,1 // Initialiser Timer 1 dans 1 seconde pour relancer Timer 1
endon

On Rules#Timer=3 do
timerSet,1,0 // Arreter Timer1
timerSet,2,0 // Arreter Timer2
gpio,13,0 // LED ON
endon

Configuration Jeedom du Sonoff 4Ch Pro (Arrosage) 192.168.0.193

Gestion de l’arrosage automatique (à 22h)

Il est programmé dans les règles du Sonoff 4chPro un déclenchement automatique à 22h.

Par défaut à l’allumage, la LED bleue s’allume et l’arrosage est automatique. Le Sonoff 4CHPro peut seul gérer l’arrosage (sans Jeedom)

Je vais bientôt ajouter un contrôle sur l’humidité, probablement une prochaine mise à jour de ce tuto.

Pour commander depuis Jeedom et pour l’intégrer facilement dans un Design, j’ai fait un virtuel « Arrosage automatique »

Dans le Dashboard

Dans le design

Configuration du virtuel